Respawning Vehicles in GTA 2 Mission Scripts

When revising my MultiSlayer map pack during July 2008, I tried creating a respawning car. I didn’t even know where to start, so I asked on Gouranga Forums. Initial code and various improvements were supplied by Sektor and are used with full permission.

Sektor and I made many refinements together, producing this bullet-proof code.

Working Example

MultiSlayer Ghetto Arena has a respawning FBI Car, armed with Vehicle Machine Guns. The code is available at the bottom of this page.

Respawn Requirements

The logic for respawning a car properly goes like this:

  1. Only respawn the car after it has been destroyed.
  2. Let the explosion play out before trying to respawn the car.
  3. Do not let players see the car being respawned.
  4. If the wreck blocks the car’s spawnpoint, remove the wreck.
  5. Otherwise, leave the wreck in the level.
  6. Respawn the car.

Every item in that list is important. Here’s why:

  1. You can spawn a new car as soon as you like but you cannot enter it.
  2. The explosion will be cancelled if you respawn the car immediately.
  3. It looks weird for a car to appear from nowhere. It also makes sure the car is not respawned on top of a player, since that will have strange effects.
  4. If the spawnpoint is blocked, you cannot move the new car. Also, you might cause a chain reaction where the new car is destroyed by the old wreck again and again. This crashes the game after a few seconds.
  5. Wrecked cars can be used tactically as the game progresses. If there are too many wrecks, GTA 2 will probably remove some.
  6. Unlike powerups, your code must do a CREATE_CAR each time to make the car respawn.

Create a Vehicle

Just like a normal mission vehicle, I create an FBI Car: 

CAR_DATA fbicar = (184.5,149.5) -1 000 EDSELFBI // FBI Car

This will appear at the start of the game.

Create a Trailer

This is part of an evil trick Sektor thought up. Define it as normal: 

PARKED_CAR_DATA trailer = (1.0,1.0) 19 90 TRUKTRNS // Car Transporter Trailer

According to the default.txt which comes with the mission compiler, a PARKED_CAR_DATA uses less resources than a CAR_DATA.

Special Vehicle Features

After your LEVELSTART you can give it weapons, like this: 

// Special cars:
GIVE_WEAPON (fbicar, CAR_MACHINE_GUN, 99)

You can also change the colour, turn on the siren and everything else. When the car respawns, it forgets these features. You must set them again each time it respawns.

Evil Tricks

There is no way to instantly delete a vehicle from the level. However, PUT_CAR_ON_TRAILER will move it onto the trailer instantly. So we can clear the wreck from the spawnpoint.

When fbicar is wrecked, it still exists as a mission vehicle. The DELETE_ITEM command tells the game it can forget about the wreck. This lets us create a new fbicar safely. The game seems to do this automatically but DELETE_ITEM makes it clearer.

Respawn Code Loop

As part of your level’s main code loop, add the respawn code: 

// Respawning FBI Car:
IF (IS_CAR_WRECKED(fbicar))
 IF (NOT (DELAY(100)) ) // let explosion happen
  IF (NOT (IS_POINT_ONSCREEN(184.5,149.5,2.0)) )
   IF (IS_CAR_IN_BLOCK(fbicar, 184.5,149.5,2.0, 1.0,1.0))
    // Wreck is blocking spawnpoint:
    PUT_CAR_ON_TRAILER (fbicar, trailer)
   ENDIF
 
   // Spawnpoint is clear:
   DELETE_ITEM (fbicar)
   fbicar = CREATE_CAR (184.5,149.5) -1 000 EDSELFBI END // FBI Car
   GIVE_WEAPON (fbicar, CAR_MACHINE_GUN, 99)
  ENDIF
 ENDIF
ENDIF

This carries out all the respawn requirements.

Working Code

All of the relevant parts put together create this: 

// MultiSlayer Ghetto by Cerbera
CAR_DATA fbicar = (184.5,149.5) -1 000 EDSELFBI // FBI Car
PARKED_CAR_DATA trailer = (1.0,1.0) 19 90 TRUKTRNS // Car Transporter Trailer


// Players:
// p3    p1
// p4 MG 
// p2 p5 p6
PLAYER_PED p1 = (186.75,153.25,255.0) 10 315
PLAYER_PED p2 = (185.25,154.75,255.0) 07 135
PLAYER_PED p3 = (185.25,153.25,255.0) 11 045
PLAYER_PED p4 = (185.05,154.00,255.0) 13 090
PLAYER_PED p5 = (186.00,154.90,255.0) 12 180
PLAYER_PED p6 = (186.75,154.75,255.0) 08 225


// Code Looping:
COUNTER loopage = 1


LEVELSTART


// Special cars:
GIVE_WEAPON (fbicar, CAR_MACHINE_GUN, 99)


// the loop
WHILE_EXEC (loopage = 1)

// Respawning FBI Car:
IF (IS_CAR_WRECKED(fbicar))
 IF (NOT (DELAY(100)) ) // let explosion happen
  IF (NOT (IS_POINT_ONSCREEN(184.5,149.5,2.0)) )
   IF (IS_CAR_IN_BLOCK(fbicar, 184.5,149.5,2.0, 1.0,1.0))
    // Wreck is blocking spawnpoint:
    PUT_CAR_ON_TRAILER (fbicar, trailer)
   ENDIF
 
   // Spawnpoint is clear:
   DELETE_ITEM (fbicar)
   fbicar = CREATE_CAR (184.5,149.5) -1 000 EDSELFBI END // FBI Car
   GIVE_WEAPON (fbicar, CAR_MACHINE_GUN, 99)
  ENDIF
 ENDIF
ENDIF

ENDWHILE

LEVELEND

Tested in single player and multiplayer many times. It works perfectly if you set it up correctly.